merged vim-config and zsh-config. added some other configs as well and makedots.sh to make links

.gitmodules

@@ -0,0 +1,30 @@
+[submodule "zsh/plugins/zsh-history-substring-search"]
+	path = zsh/plugins/zsh-history-substring-search
+	url = https://github.com/zsh-users/zsh-history-substring-search
+[submodule "zsh/plugins/zsh-syntax-highlighting"]
+	path = zsh/plugins/zsh-syntax-highlighting
+	url = https://github.com/zsh-users/zsh-syntax-highlighting
+[submodule "vim/bundle/undotree"]
+	path = vim/bundle/undotree
+	url = https://github.com/mbbill/undotree
+[submodule "vim/bundle/vim-geeknote"]
+	path = vim/bundle/vim-geeknote
+	url = https://github.com/neilagabriel/vim-geeknote
+[submodule "vim/bundle/syntastic"]
+	path = vim/bundle/syntastic
+	url = https://github.com/scrooloose/syntastic
+[submodule "vim/bundle/mru.vim"]
+	path = vim/bundle/mru.vim
+	url = https://github.com/vim-scripts/mru.vim
+[submodule "vim/bundle/vim-fugitive"]
+	path = vim/bundle/vim-fugitive
+	url = https://github.com/tpope/vim-fugitive
+[submodule "vim/bundle/vimux"]
+	path = vim/bundle/vimux
+	url = https://github.com/benmills/vimux
+[submodule "vim/bundle/vim-airline"]
+	path = vim/bundle/vim-airline
+	url = https://github.com/vim-airline/vim-airline
+[submodule "vim/bundle/YouCompleteMe"]
+	path = vim/bundle/YouCompleteMe
+	url = https://github.com/Valloric/YouCompleteMe

bashrc

@@ -0,0 +1,30 @@
+PS1='\[\e[1;32m\]\u@\h \W\$ \[\e[0m\]'
+
+# ls pleasantness
+alias l='\ls --color=auto'
+alias ls='ls -a --color=auto'
+alias lls='ls -alh --color=auto'
+
+# grep the entirety of the history
+alias hg='history | grep'
+
+# Use vim as the default text editor
+export VISUAL=vim
+
+# local folder in PATH 
+export PATH=$HOME/bin:$PATH
+
+# Flags used for CS243 "Mechanics of Programming"
+alias gcc='gcc -std=c99 -Wall -ggdb -Wextra -pedantic'
+
+# Functions for converting between hex and decimal
+h2d(){
+    echo "ibase=16; $@"|bc
+  }
+d2h(){
+    echo "obase=16; $@"|bc
+}
+
+# alias for vim muscle memory when quitting
+alias :q='exit'
+alias :e='vim'

gvimrc

@@ -0,0 +1,5 @@
+set lines=30 columns=100    " set inital window size
+set ruler
+colorscheme vividchalk
+set guioptions-=T  "remove menu bar
+set mouse= " disable mouse

makedots.sh

@@ -0,0 +1,14 @@
+DIR=$(pwd)
+cd ~
+rm -i .vimrc
+ln -s $DIR/vimrc .vimrc
+rm -i .vim
+ln -s $DIR/vim .vim
+
+rm -i .zshrc
+ln -s $DIR/zshrc .zshrc
+rm -i .zsh
+ln -s $DIR/zsh .zsh
+
+rm -i .bashrc
+ln -s $DIR/bashrc .bashrc

vim/CapsEsc.ahk

@@ -0,0 +1,2 @@
+#SingleInstance ignore
+Capslock::Esc

vim/autoload/pathogen.vim

@@ -0,0 +1,353 @@
+" pathogen.vim - path option manipulation
+" Maintainer:   Tim Pope <http://tpo.pe/>
+" Version:      2.4
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below.
+
+if exists("g:loaded_pathogen") || &cp
+  finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage.  Give a relative path to invoke
+" pathogen#interpose() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround().  Curly braces are expanded with pathogen#expand():
+" "bundle/{}" finds all subdirectories inside "bundle" inside all directories
+" in the runtime path.
+function! pathogen#infect(...) abort
+  for path in a:0 ? filter(reverse(copy(a:000)), 'type(v:val) == type("")') : ['bundle/{}']
+    if path =~# '^\%({\=[$~\\/]\|{\=\w:[\\/]\).*[{}*]'
+      call pathogen#surround(path)
+    elseif path =~# '^\%([$~\\/]\|\w:[\\/]\)'
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#surround(path . '/{}')
+    elseif path =~# '[{}*]'
+      call pathogen#interpose(path)
+    else
+      call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+      call pathogen#interpose(path . '/{}')
+    endif
+  endfor
+  call pathogen#cycle_filetype()
+  if pathogen#is_disabled($MYVIMRC)
+    return 'finish'
+  endif
+  return ''
+endfunction
+
+" Split a path into a list.
+function! pathogen#split(path) abort
+  if type(a:path) == type([]) | return a:path | endif
+  if empty(a:path) | return [] | endif
+  let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+  return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction
+
+" Convert a list to a path.
+function! pathogen#join(...) abort
+  if type(a:1) == type(1) && a:1
+    let i = 1
+    let space = ' '
+  else
+    let i = 0
+    let space = ''
+  endif
+  let path = ""
+  while i < a:0
+    if type(a:000[i]) == type([])
+      let list = a:000[i]
+      let j = 0
+      while j < len(list)
+        let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+        let path .= ',' . escaped
+        let j += 1
+      endwhile
+    else
+      let path .= "," . a:000[i]
+    endif
+    let i += 1
+  endwhile
+  return substitute(path,'^,','','')
+endfunction
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort
+  return call('pathogen#join',[1] + a:000)
+endfunction
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() abort
+  if exists('g:did_load_filetypes')
+    filetype off
+    filetype on
+  endif
+endfunction
+
+" Check if a bundle is disabled.  A bundle is considered disabled if its
+" basename or full name is included in the list g:pathogen_blacklist or the
+" comma delimited environment variable $VIMBLACKLIST.
+function! pathogen#is_disabled(path) abort
+  if a:path =~# '\~$'
+    return 1
+  endif
+  let sep = pathogen#slash()
+  let blacklist =
+        \ get(g:, 'pathogen_blacklist', get(g:, 'pathogen_disabled', [])) +
+        \ pathogen#split($VIMBLACKLIST)
+  if !empty(blacklist)
+    call map(blacklist, 'substitute(v:val, "[\\/]$", "", "")')
+  endif
+  return index(blacklist, fnamemodify(a:path, ':t')) != -1 || index(blacklist, a:path) != -1
+endfunction
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory.  Curly braces are expanded with pathogen#expand().
+function! pathogen#surround(path) abort
+  let sep = pathogen#slash()
+  let rtp = pathogen#split(&rtp)
+  let path = fnamemodify(a:path, ':s?[\\/]\=$??')
+  let before = filter(pathogen#expand(path), '!pathogen#is_disabled(v:val)')
+  let after = filter(reverse(pathogen#expand(path, sep.'after')), '!pathogen#is_disabled(v:val[0:-7])')
+  call filter(rtp, 'index(before + after, v:val) == -1')
+  let &rtp = pathogen#join(before, rtp, after)
+  return &rtp
+endfunction
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended.  Curly braces are expanded with pathogen#expand().
+function! pathogen#interpose(name) abort
+  let sep = pathogen#slash()
+  let name = a:name
+  if has_key(s:done_bundles, name)
+    return ""
+  endif
+  let s:done_bundles[name] = 1
+  let list = []
+  for dir in pathogen#split(&rtp)
+    if dir =~# '\<after$'
+      let list += reverse(filter(pathogen#expand(dir[0:-6].name, sep.'after'), '!pathogen#is_disabled(v:val[0:-7])')) + [dir]
+    else
+      let list += [dir] + filter(pathogen#expand(dir.sep.name), '!pathogen#is_disabled(v:val)')
+    endif
+  endfor
+  let &rtp = pathogen#join(pathogen#uniq(list))
+  return 1
+endfunction
+
+let s:done_bundles = {}
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort
+  let sep = pathogen#slash()
+  for glob in pathogen#split(&rtp)
+    for dir in map(split(glob(glob), "\n"), 'v:val.sep."/doc/".sep')
+      if (dir)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir) == 2 && !empty(split(glob(dir.'*.txt'))) && (!filereadable(dir.'tags') || filewritable(dir.'tags'))
+        silent! execute 'helptags' pathogen#fnameescape(dir)
+      endif
+    endfor
+  endfor
+endfunction
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command.  This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort
+  for command in a:000
+    execute command
+  endfor
+  return ''
+endfunction
+
+" Section: Unofficial
+
+function! pathogen#is_absolute(path) abort
+  return a:path =~# (has('win32') ? '^\%([\\/]\|\w:\)[\\/]\|^[~$]' : '^[/~$]')
+endfunction
+
+" Given a string, returns all possible permutations of comma delimited braced
+" alternatives of that string.  pathogen#expand('/{a,b}/{c,d}') yields
+" ['/a/c', '/a/d', '/b/c', '/b/d'].  Empty braces are treated as a wildcard
+" and globbed.  Actual globs are preserved.
+function! pathogen#expand(pattern, ...) abort
+  let after = a:0 ? a:1 : ''
+  if a:pattern =~# '{[^{}]\+}'
+    let [pre, pat, post] = split(substitute(a:pattern, '\(.\{-\}\){\([^{}]\+\)}\(.*\)', "\\1\001\\2\001\\3", ''), "\001", 1)
+    let found = map(split(pat, ',', 1), 'pre.v:val.post')
+    let results = []
+    for pattern in found
+      call extend(results, pathogen#expand(pattern))
+    endfor
+  elseif a:pattern =~# '{}'
+    let pat = matchstr(a:pattern, '^.*{}[^*]*\%($\|[\\/]\)')
+    let post = a:pattern[strlen(pat) : -1]
+    let results = map(split(glob(substitute(pat, '{}', '*', 'g')), "\n"), 'v:val.post')
+  else
+    let results = [a:pattern]
+  endif
+  let vf = pathogen#slash() . 'vimfiles'
+  call map(results, 'v:val =~# "\\*" ? v:val.after : isdirectory(v:val.vf.after) ? v:val.vf.after : isdirectory(v:val.after) ? v:val.after : ""')
+  return filter(results, '!empty(v:val)')
+endfunction
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#slash() abort
+  return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction
+
+function! pathogen#separator() abort
+  return pathogen#slash()
+endfunction
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort
+  let files = split(glob(a:pattern),"\n")
+  return map(files,'substitute(v:val,"[".pathogen#slash()."/]$","","")')
+endfunction
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort
+  return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort
+  let i = 0
+  let seen = {}
+  while i < len(a:list)
+    if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+      call remove(a:list,i)
+    elseif a:list[i] ==# ''
+      let i += 1
+      let empty = 1
+    else
+      let seen[a:list[i]] = 1
+      let i += 1
+    endif
+  endwhile
+  return a:list
+endfunction
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort
+  if exists('*fnameescape')
+    return fnameescape(a:string)
+  elseif a:string ==# '-'
+    return '\-'
+  else
+    return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+  endif
+endfunction
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort
+  let rtp = pathogen#join(1,pathogen#split(&rtp))
+  let file = findfile(a:file,rtp,a:count)
+  if file ==# ''
+    return ''
+  else
+    return fnamemodify(file,':p')
+  endif
+endfunction
+
+" Section: Deprecated
+
+function! s:warn(msg) abort
+  echohl WarningMsg
+  echomsg a:msg
+  echohl NONE
+endfunction
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.  Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) abort
+  call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#infect('.string(a:path.'/{}').')')
+  return pathogen#surround(a:path . pathogen#slash() . '{}')
+endfunction
+
+function! pathogen#incubate(...) abort
+  let name = a:0 ? a:1 : 'bundle/{}'
+  call s:warn('Change pathogen#incubate('.(a:0 ? string(a:1) : '').') to pathogen#infect('.string(name).')')
+  return pathogen#interpose(name)
+endfunction
+
+" Deprecated alias for pathogen#interpose().
+function! pathogen#runtime_append_all_bundles(...) abort
+  if a:0
+    call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#infect('.string(a:1.'/{}').')')
+  else
+    call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#infect()')
+  endif
+  return pathogen#interpose(a:0 ? a:1 . '/{}' : 'bundle/{}')
+endfunction
+
+if exists(':Vedit')
+  finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd)
+  let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+  let file = pathogen#runtime_findfile(a:file,a:count)
+  if file ==# ''
+    return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+  endif
+  if !s:vopen_warning
+    let s:vopen_warning = 1
+    let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+  else
+    let warning = ''
+  endif
+  if a:lcd
+    let path = file[0:-strlen(a:file)-2]
+    execute 'lcd `=path`'
+    return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+  else
+    return a:cmd.' '.pathogen#fnameescape(file) . warning
+  endif
+endfunction
+
+function! s:Findcomplete(A,L,P)
+  let sep = pathogen#slash()
+  let cheats = {
+        \'a': 'autoload',
+        \'d': 'doc',
+        \'f': 'ftplugin',
+        \'i': 'indent',
+        \'p': 'plugin',
+        \'s': 'syntax'}
+  if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+    let request = cheats[a:A[0]].a:A[1:-1]
+  else
+    let request = a:A
+  endif
+  let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+  let found = {}
+  for path in pathogen#split(&runtimepath)
+    let path = expand(path, ':p')
+    let matches = split(glob(path.sep.pattern),"\n")
+    call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+    call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+    for match in matches
+      let found[match] = 1
+    endfor
+  endfor
+  return sort(keys(found))
+endfunction
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve       :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit    :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen    :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit   :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit  :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit   :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread    :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2 foldmethod=expr foldexpr=getline(v\:lnum)=~'^\"\ Section\:'?'>1'\:getline(v\:lnum)=~#'^fu'?'a1'\:getline(v\:lnum)=~#'^endf'?'s1'\:'=':

vim/bundle/YouCompleteMe

@@ -0,0 +1 @@
+Subproject commit cb5756943fdd3ba062f101a5aba34acdd34d1356

vim/bundle/mru.vim

@@ -0,0 +1 @@
+Subproject commit 9f25db66393a6467fae0ac04ae6565e8471023c3

vim/bundle/syntastic

@@ -0,0 +1 @@
+Subproject commit 23abc77a83a91c918e19e6967245561c6867bafd

vim/bundle/undotree

@@ -0,0 +1 @@
+Subproject commit e5a01b2eb94afd256a96cac07ba2981a55dd9665

vim/bundle/vim-airline

@@ -0,0 +1 @@
+Subproject commit 30f078daf569e7d5e4f7829e39316387af349b41

vim/bundle/vim-fugitive

@@ -0,0 +1 @@
+Subproject commit bdd216827ae53cdf70d933bb30762da9bf42cad4

vim/bundle/vim-geeknote

@@ -0,0 +1 @@
+Subproject commit 7f040f655bc5a8f98185c1e161bd4cba977f5664

vim/bundle/vimux

@@ -0,0 +1 @@
+Subproject commit 2285cefee9dfb2139ebc8299d11a6c8c0f21309e

vim/undodir/.gitignore

@@ -0,0 +1,2 @@
+*
+!.gitignore

vimrc

@@ -0,0 +1,181 @@
+" start plugins
+execute pathogen#infect()
+
+" set black color scheme
+colorscheme torte
+" enable syntax processing
+syntax enable
+
+" number of visual spaces per TAB
+set tabstop=4
+
+" number of spaces in tab when editing
+set softtabstop=4
+
+" number of space when using > or <
+set shiftwidth=4	
+
+" tabs are spaces
+set expandtab		
+
+" show line numbers
+set number		
+
+" show command in bottom bar
+set showcmd		
+
+" highlight current line
+set cursorline		
+
+" load filetype-specific indent files
+filetype indent on	
+
+" visual autocomplete for command menu
+set wildmenu		
+
+" redraw only when necessary (faster macros)
+set lazyredraw		
+
+" highlight matching brackets
+set showmatch		
+
+" search as characters are entered
+set incsearch   
+
+" fold based on indent
+set foldmethod=indent   
+
+" foldlevel when window is loaded
+set foldlevelstart=1   
+
+" space is Leader
+map <space> <leader>
+
+" fold based on indent level
+set foldmethod=indent	
+
+" set shell to zsh (if it exists)
+if !(has("win32") || has("win16") || has("win32unix"))
+    if filereadable("/bin/zsh")
+        silent! set shell=/bin/zsh  
+    endif
+endif
+
+" function to check for running instances of vim on Linux
+function! UnixCapsControl()
+    silent! let running = system('echo $(pgrep -c vim)')
+    if(running <= 1)
+        silent! !xmodmap -e 'clear Lock' -e 'keycode 0x42 = Caps_Lock'
+    endif
+endfunction
+
+" map caps lock to escape under Linux
+if !(has("win32") || has("win16") || has("win32unix"))
+    au VimEnter * silent! !xmodmap -e 'clear Lock' -e 'keycode 0x42 = Escape'
+    au VimLeave * :call UnixCapsControl() 
+endif
+
+" function to check for running instances of vim on Windows
+function! WindowsCapsControl()
+    silent! let running = system('tasklist /FI "IMAGENAME eq vim.exe" 2>NUL | find /I /C "vim.exe"')
+    if(running <= 1)
+        silent! !start taskkill /IM CapsEsc.exe
+    endif
+endfunction
+
+" map caps lock to escape under Windows
+if (has("win32") || has("win16"))
+    au VimEnter * silent! !start C:\Users\Josh\vimfiles\CapsEsc.exe
+    au VimLeave * :call WindowsCapsControl()
+endif
+"
+" function to check for running instances of vim on Cygwin
+function! CygwinCapsControl()
+    silent! let running = system('echo $(pgrep -c vim)')
+    if(running <= 1)
+        silent! !pkill CapsEsc
+    endif
+endfunction
+
+" map caps lock to excape under Cygwin
+if (has("win32unix"))
+    au VimEnter * silent! !/home/josh/.vim/CapsEsc.exe &
+    au VimLeave * :call CygwinCapsControl()
+endif
+
+" swap files are rotated every 10 keystrokes
+set updatecount=10  
+
+" backspace is used to remove previous characters, indents, and newlines
+set backspace=indent,eol,start	
+
+" <Leader>l formats a line
+noremap <Leader>l Vgq   
+
+" make an undo file to allow undoing after closing a file
+set undofile
+set undodir=~/.vim/undodir
+
+" set Makefiles with tabs not spaces
+autocmd FileType make setlocal noexpandtab
+
+" compare current buffer to saved file
+function! s:DiffWithSaved()
+  let filetype=&ft
+  diffthis
+  vnew | r # | normal! 1Gdd
+  diffthis
+  exe "setlocal bt=nofile bh=wipe nobl noswf ro ft=" . filetype
+endfunction
+com! DiffSaved call s:DiffWithSaved()
+
+" map the comp buff function above
+noremap <Leader>d :DiffSaved<CR>
+
+" function to write a file and immediately run make
+function! s:writeAndMake()
+    :w
+    :make
+endfunction
+com! WriteMake call s:writeAndMake()
+
+" map the write and make function
+noremap <Leader>c :WriteMake<CR>
+
+" write w/ privileges when Vim isn't started as root
+cmap w!! %!sudo tee > /dev/null %
+
+" plugins
+
+" show recently opened files
+noremap <Leader>m :MRU<CR>  
+
+" Start Geeknote
+noremap <Leader>g :Geeknote<CR>  
+
+" show undo tree
+noremap <Leader>u :UndotreeToggle<CR>  
+
+" syntastic 
+if exists(':SyntasticStatuslineFlag()')
+    set statusline+=%#warningmsg#
+    set statusline+=%{SyntasticStatuslineFlag()}
+    set statusline+=%*
+
+    let g:syntastic_always_populate_loc_list = 1
+    let g:syntastic_auto_loc_list = 1
+    let g:syntastic_check_on_open = 1
+    let g:syntastic_check_on_wq = 0
+endif
+
+" YouCompleteMe
+let g:ycm_global_ycm_extra_conf = '~/.vim/bundle/YouCompleteMe/third_party/ycmd/examples/.ycm_extra_conf.py'    
+" autoclose suggestion windows
+let g:ycm_autoclose_preview_window_after_insertion=1
+
+" colors
+highlight YcmWarningSection ctermfg=Yellow
+highlight YcmWarningSign ctermfg=Yellow
+
+highlight YcmErrorSection ctermfg=Red
+highlight YcmErrorsign ctermfg=Red

zsh/plugins/zsh-history-substring-search

@@ -0,0 +1 @@
+Subproject commit f5c164d4c3af1f5bd068ee10f88b4c7b3a1fd841

zsh/plugins/zsh-syntax-highlighting

@@ -0,0 +1 @@
+Subproject commit 4da9889d154509a8ee30605618d2256cf511cae4

zshrc

@@ -0,0 +1,91 @@
+# Lines configured by zsh-newuser-install
+HISTFILE=~/.histfile
+HISTSIZE=1000
+SAVEHIST=1000
+setopt appendhistory autocd extendedglob nomatch
+bindkey -e
+# End of lines configured by zsh-newuser-install
+# The following lines were added by compinstall
+zstyle :compinstall filename '/home/josh/.zshrc'
+
+autoload -Uz compinit
+compinit
+# End of lines added by compinstall
+
+# Use prompt colors (green for regular user, red for root)
+autoload -U colors && colors
+if [ "$(id -u)" != "0" ]; then
+    PROMPT="%{$fg_bold[green]%}%n@%m %1~ $%{$reset_color%} "
+    RPROMPT="[%{$fg_no_bold[yellow]%}%?%{$reset_color%}]"
+else
+    PROMPT="%{$fg_bold[red]%}%n@%m %1~ #%{$reset_color%} "
+    RPROMPT="[%{$fg_no_bold[yellow]%}%?%{$reset_color%}]"
+fi
+
+# ls pleasantness
+alias l='\ls --color=auto'
+alias ls='ls --color=auto'
+alias lsa='ls -a --color=auto'
+alias lls='ls -alh --color=auto'
+
+# apt-get aliases 
+alias update='sudo apt-get update && sudo apt-get dist-upgrade' 
+alias clean='sudo apt-get clean'
+
+# grep the entirety of the history
+alias hg='history 1 | grep'
+
+# Use vim as the default text editor
+export VISUAL=vim
+
+# Used to keep steam from throwing errors
+export SWT_GTK3=0
+
+# Home and End keysjump the the beginning/end of the command
+bindkey "^[OH" beginning-of-line
+bindkey "^[OF" end-of-line
+
+# Ctrl-Left and Ctrl-Right keys move between words
+bindkey ";5C" forward-word
+bindkey ";5D" backward-word
+
+# bind UP and DOWN arrow keys
+bindkey '^[[A' history-substring-search-up
+bindkey '^[[B' history-substring-search-down
+
+# Used for X forwarding in Cygwin
+if [[ "$(uname -o)" != "GNU/Linux" ]]; then
+    DISPLAY=:1.0
+fi
+
+# local folder in PATH for UE4
+export PATH=$HOME/bin:$PATH
+
+# Flags used for CS243 "Mechanics of Programming"
+alias gcc='gcc -std=c99 -Wall -ggdb -Wextra -pedantic'
+
+# Functions for converting between hex and decimal
+h2d(){
+    echo "ibase=16; $@"|bc
+  }
+d2h(){
+    echo "obase=16; $@"|bc
+}
+
+# devkitPro/devkitPPC sources
+export DEVKITPRO=/home/josh/devkitPro/ 
+export DEVKITPPC=/home/josh/devkitPro//devkitPPC
+
+# alias for vim muscle memory when quitting
+alias :q='exit'
+
+# eval used by thefuck
+if hash fuck 2>/dev/null; then
+    eval $(thefuck --alias)
+fi
+
+# zsh-syntax-highlighting (MUST BE AT THE BOTTOM OF THIS FILE)
+source ~/.zsh/plugins/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh
+
+# zsh-history-substring-search (MUST BE BELOW SYNTAX HIGHLIGHTING)
+source ~/.zsh/plugins/zsh-history-substring-search/zsh-history-substring-search.zsh